//Aims a meteor-like shot at the player

script_enemy_main{

let GRenemy=("\script\Images\Enemies\Fairy2-13.png");
let SEshot1=("script\SoundEffects\shotb1.wav");
let SEdeath=("script\SoundEffects\enemydeath1.wav");
let miny=GetClipMinY; let maxy=GetClipMaxY; let minx=GetClipMinX; let maxx=GetClipMaxX;
let cx=GetCenterX; let cy=GetCenterY;
let startx=GetX; let starty=GetY;
let frame=0; let time=0; let animation=0;
let ani=4;
let scale=0.75;
let shots=0;
let oldX=0; let oldY=0;
let invincible=125;

let shoottime=rand_int(10,30);

if(startx<cx){ SetAngle(0+rand(-10,0)); }
if(startx>cx){ SetAngle(180+rand(0,10)); }
SetSpeed(2.5);

@Initialize{
	LoadGraphic("\script\Images\Enemies\Fairy2-13.png");
	LoadSE("script\SoundEffects\shotb1.wav");

	SetInvincibility(40);
	SetLife(12);
	SetDamageRate(10,3); 
	SetScore(1000);
	SetShotColor(255,255,255);
}

@MainLoop{

if(GetX<=minx-32 || GetX>=maxx+32 || GetY<=miny-32 || GetY>=maxy+32 && frame>=60){ VanishEnemy; }

if((GetX>minx && GetX<maxx) && (GetY>miny && GetY<maxy)){
SetCollisionA(GetX,GetY,32*scale);
SetCollisionB(GetX,GetY,32*scale);

if(GetCommonData("Difficulty")==1){
	if((time+shoottime)%60==0 && time>=50 && shots<2){
	let speed=1.5;
	let color=155;
		loop(3){
		SetShotColor(color,color,color);
		CreateShot01(GetX,GetY,speed,GetAngleToPlayer+rand(-2.5,2.5),44,10);
		SetShotColor(255,255,255);
		color+=20;
		speed+=2/3;
		}
	CreateShot01(GetX,GetY,speed,GetAngleToPlayer,56,10);
	shots++;
	PlaySE(SEshot1);
	}
} //Easy

if(GetCommonData("Difficulty")==2){
	if((time+shoottime)%60==0 && time>=40 && shots<2){
	let speed=1.5;
	let color=155;
		loop(5){
		SetShotColor(color,color,color);
		CreateShot01(GetX,GetY,speed,GetAngleToPlayer+rand(-1.5,1.5),44,10);
		SetShotColor(255,255,255);
		color+=10;
		speed+=2/5;
		}
	CreateShot01(GetX,GetY,speed,GetAngleToPlayer,56,10);
	shots++;
	PlaySE(SEshot1);
	}
} //Normal

if(GetCommonData("Difficulty")==3){
	if((time+shoottime)%60==0 && time>=30 && shots<2){
	let speed=2.25;
	let color=155;
		loop(7){
		SetShotColor(color,color,color);
		CreateShot01(GetX,GetY,speed*0.85,GetAngleToPlayer-15+rand(-0.5,0.5),44,10);
		CreateShot01(GetX,GetY,speed,GetAngleToPlayer+rand(-0.5,0.5),44,10);
		CreateShot01(GetX,GetY,speed*0.85,GetAngleToPlayer+15+rand(-0.5,0.5),44,10);
		SetShotColor(255,255,255);
		color+=10;
		speed+=2/6;
		}
	CreateShot01(GetX,GetY,speed*0.85,GetAngleToPlayer-15,56,10);
	CreateShot01(GetX,GetY,speed,GetAngleToPlayer,56,10);
	CreateShot01(GetX,GetY,speed*0.85,GetAngleToPlayer+15,56,10);
	shots++;
	PlaySE(SEshot1);
	}
} //Hard

if(GetCommonData("Difficulty")==4){
	if((time+shoottime)%60==0 && time>=20 && shots<3){
	let speed=3;
	let color=155;
		loop(10){
		SetShotColor(color,color,color);
		CreateShot01(GetX,GetY,speed*0.9,GetAngleToPlayer-12,44,0);
		CreateShot01(GetX,GetY,speed,GetAngleToPlayer,44,0);
		CreateShot01(GetX,GetY,speed*0.9,GetAngleToPlayer+12,44,0);
		SetShotColor(255,255,255);
		color+=10;
		speed+=3/10;
		}
	CreateShot01(GetX,GetY,speed*0.9,GetAngleToPlayer-12,56,0);
	CreateShot01(GetX,GetY,speed,GetAngleToPlayer,56,0);
	CreateShot01(GetX,GetY,speed*0.9,GetAngleToPlayer+12,56,0);
	shots++;
	PlaySE(SEshot1);
	}
} //Lunatic
} //Onscreen


if(time>=60 && time<120){ SetSpeed(GetSpeed-0.03); }
if(time>=120 && startx<cx){ SetAngle(GetAngle+1); SetSpeed(GetSpeed+0.01); }
if(time>=120 && startx>cx){ SetAngle(GetAngle-1); SetSpeed(GetSpeed+0.01); }


oldX=GetX;
oldY=GetY;
frame++;
time++;
animation++;
if(animation>=ani*6){ animation=0; }
if(GetTimeOfInvincibility<25 && invincible>0){ invincible=GetTimeOfInvincibility*5; }

}

@DrawLoop{
let side=0;
	SetTexture(GRenemy);
		if(oldX<GetX || oldX>GetX){ side=128; }
		if(animation>=ani*0 && animation<ani*1){ SetGraphicRect(1,side,256,128+side); }
		if(animation>=ani*1 && animation<ani*2){ SetGraphicRect(257,side,512,128+side); }
		if(animation>=ani*2 && animation<ani*3){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*3 && animation<ani*4){ SetGraphicRect(769,side,1024,128+side); }
		if(animation>=ani*4 && animation<ani*5){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*5 && animation<ani*6){ SetGraphicRect(257,side,512,128+side); }
	SetGraphicAngle(0,0,0);
	if(oldX<GetX){ SetGraphicAngle(180,0,0); }
	SetGraphicScale(scale,scale);
	SetColor(255-invincible,255-invincible,255);
	DrawGraphic(GetX,GetY);
}

@Finalize{
if(BeVanished==false){
PlaySE(SEdeath);
	loop(3){ CreateEnemyFromFile("script\Functions\itempoint.txt",GetX+rand(-50,50),GetY+rand(-50,50),0,0,0); }
	loop(2){ CreateEnemyFromFile("script\Functions\itempower.txt",GetX+rand(-50,50),GetY+rand(-50,50),0,0,0); }
#include_function "script/Functions/PlayerTypeBonus.txt";
}
}

}